Automate E-Mail Signatures (Exchange 2007/Outlook) (Full Version)

All Forums >> [Microsoft Exchange 2007] >> Management



Message

smartdrv -> Automate E-Mail Signatures (Exchange 2007/Outlook) (6.Jun.2007 12:22:28 PM)

Hello

Been playing with some of Exchange 2007's features (some are probably in 2003 but I haven't touched them much).

I've learned that I can use hub transport rules to do some cool things like attach a disclaimer to outgoing messages (with all sorts of filtering options like not on internal messages). It's really cool.

This got me thinking of the next level. Signatures. Ideally signatures that will pull the information (names, numbers, titles, address) out of Active Directory. Simple is ok although the ability to toss in a logo could be cool too.

Two thoughts, either totally automated like the disclaimer (which I think would have the advantage of working in Outlook Web Access as well) or via the Outlook (2007 or possibly 2003) client (again either automated or give the user something to click - there is a Signiture button in Outlook)

I'd like to do this in the method that has the least administrative overhead (scripting and policies - something so I don't have to manually touch anything on the clients and it just works)

Any suggestions on where to start? I'm sure that this is something that many of the admins on this forum have probably delt with.

Much thanks as always!
Rob



Studon -> RE: Automate E-Mail Signatures (Exchange 2007/Outlook) (12.Jul.2007 12:04:01 PM)

Hello,

I am just looking into doing just that.  If you happen to come across any info on this please let me know or post here.  I will do the same.

We have used a third party app in the past but it was an added cost due to licences and we would like to utilize E2K7 to do this if it is possible.

Good luck in your search and I hope we can find something to facilitate this.



a.grogan -> RE: Automate E-Mail Signatures (Exchange 2007/Outlook) (12.Jul.2007 4:44:11 PM)

Hey Guys, have you folks seen this article here http://www.microsoft.com/technet/technetmag/issues/2006/10/HeyScriptingGuy/default.aspx

Its not part of Exchange 2007, but can simply be added into a logon script and then second script in the download package allows your to draw data from AD.

Just a thought,

A



stuarta -> RE: Automate E-Mail Signatures (Exchange 2007/Outlook) (7.Aug.2007 10:09:39 AM)

Ok, just downloaded this and looks as though it's exactly what I wanted, but struggling to configure it.

I've managed to pull out most of it, but want to add fax number and web address, and be able to show the difference in fax and phone number.  Also it's got carriage returns between each line and want to put some lines such as title in bold.

On Error Resume Next
Set objSysInfo = CreateObject("ADSystemInfo")
strUser = objSysInfo.UserName
Set objUser = GetObject("LDAP://" & strUser)
strName = objUser.FullName
strTitle = objUser.Title
strCompany = objUser.company
strAddress = objUser.streetAddress
strCounty = objUser.St
strPhone = objUser.telephoneNumber
strFax = objUser.faxnumber
Set objWord = CreateObject("Word.Application")
Set objDoc = objWord.Documents.Add()
Set objSelection = objWord.Selection
Set objEmailOptions = objWord.EmailOptions
Set objSignatureObject = objEmailOptions.EmailSignature
Set objSignatureEntries = objSignatureObject.EmailSignatureEntries
objSelection.TypeText strName & ", "
objSelection.TypeParagraph()
objSelection.TypeText strTitle
objSelection.TypeParagraph()
objSelection.TypeText strCompany
objSelection.TypeParagraph()
objSelection.TypeText strAddress
objSelection.TypeParagraph()
objSelection.TypeText strCounty
objSelection.TypeParagraph()
objSelection.TypeText strCompany
objSelection.TypeParagraph()
objSelection.TypeText strPhone
objSelection.TypeParagraph()
objSelection.TypeText strFax
Set objSelection = objDoc.Range()
objSignatureEntries.Add "AD Signature", objSelection
objSignatureObject.NewMessageSignature = "AD Signature"
objSignatureObject.ReplyMessageSignature = "AD Signature"
objDoc.Saved = True
objWord.Quit



stuarta -> RE: Automate E-Mail Signatures (Exchange 2007/Outlook) (16.Aug.2007 11:24:02 AM)

ok managed this now

On Error Resume Next
Set objSysInfo = CreateObject("ADSystemInfo")
strUser = objSysInfo.UserName
Set objUser = GetObject("LDAP://" & strUser)
strName = objUser.FullName
strTitle = objUser.Title
strCompany = objUser.company
strAddress = objUser.streetAddress
strCounty = objUser.St
strPhone = objUser.telephoneNumber
strFax = objUser.faxnumber
strWeb = onjuser.wwwhomepage
Set objWord = CreateObject("Word.Application")
Set objDoc = objWord.Documents.Add()
Set objSelection = objWord.Selection
Set objRange = objDoc.Range()
Set objEmailOptions = objWord.EmailOptions
Set objSignatureObject = objEmailOptions.EmailSignature
Set objSignatureEntries = objSignatureObject.EmailSignatureEntries
objSelection.Font.Size = "11"
objSelection.Font.Name = "Calibri"

objSelection.TypeText "Kind Regards"
objSelection.TypeParagraph()
objSelection.TypeParagraph()
objSelection.Font.Bold = true
objSelection.TypeText strName & ", "
objSelection.Font.Bold = false
objSelection.TypeParagraph()
objSelection.TypeText strTitle
objSelection.TypeParagraph()
objSelection.Font.Bold = true
objSelection.TypeText strCompany
objSelection.Font.Bold = false
objSelection.TypeParagraph()
objSelection.TypeText strAddress
objSelection.TypeParagraph()
objSelection.TypeText strCounty
objSelection.TypeParagraph()
objSelection.TypeText strCompany
objSelection.TypeParagraph()
objSelection.TypeText "(t) " & strPhone
objSelection.TypeParagraph()
objSelection.TypeText strFax
Set objSelection = objDoc.Range()
objSignatureEntries.Add "AD Signature", objSelection
objSignatureObject.NewMessageSignature = "AD Signature"
objSignatureObject.ReplyMessageSignature = "AD Signature"
objDoc.Saved = True
objWord.Quit


Need to take the space out between the name and title and also spaces in the address.  If I take the objSelection.TypeParagraph() it just appears on one line.

I want it to appear as


Name
Title

Company Name
Address1
Address2
Town
Post Code



felipeg007 -> RE: Automate E-Mail Signatures (Exchange 2007/Outlook) (3.Mar.2008 5:50:02 PM)


This should fix your spacing issue.

objSelection.Style = "No Spacing"
 
 



hupakyee -> RE: Automate E-Mail Signatures (Exchange 2007/Outlook) (16.May2008 2:42:10 AM)

Hi, I'm new to Exchange 2007 and was interested with Automated signature, can you please advice where can get info in details for this?



felipeg007 -> RE: Automate E-Mail Signatures (Exchange 2007/Outlook) (16.Jun.2008 10:50:52 AM)

Below is a signature i use. it grabs all the info from AD.

___________________________________________________


On Error Resume Next
Set objSysInfo = CreateObject("ADSystemInfo")
strUser = objSysInfo.UserName
Set objUser = GetObject("LDAP://" & strUser)
strName = objUser.FullName
strTitle = objUser.Title
strCompany = objUser.company
strAddress = objUser.streetAddress
strCounty = objUser.St
strPostal = objUser.postalCode
strPhone = objUser.telephoneNumber
strFax = objUser.faxnumber
strWeb = objUser.wwwhomepage

Set objWord = CreateObject("Word.Application")
Set objDoc = objWord.Documents.Add()
Set objSelection = objWord.Selection
Set objRange = objDoc.Range()
Set objEmailOptions = objWord.EmailOptions
Set objSignatureObject = objEmailOptions.EmailSignature
Set objSignatureEntries = objSignatureObject.EmailSignatureEntries
objSelection.Font.Size = "10"
objSelection.Font.Name = "Arial"
objSelection.Font.Color = "669999"
objSelection.Style = "No Spacing"
objSelection.TypeText "Thank you,"
objSelection.TypeParagraph()
objSelection.Font.Bold = true
objSelection.TypeText strName 
objSelection.Font.Bold = false
objSelection.TypeParagraph()
objSelection.TypeText strTitle
objSelection.TypeText "   |   " 
objSelection.Font.Bold = true
objSelection.Hyperlinks.Add objSelection.range, strWeb, , , strCompany
'objSelection.TypeText strCompany
objSelection.Font.Bold = false
objSelection.TypeParagraph()
objSelection.TypeText strAddress & ", "
objSelection.TypeText strCounty  & " "
objSelection.TypeText strPostal
objSelection.TypeText "   |   "
objSelection.TypeText "Office & Fax: " & strPhone
objSelection.ClearFormatting()
Set objSelection = objDoc.Range()
objSignatureEntries.Add "AD Signature", objSelection
objSignatureObject.NewMessageSignature = "AD Signature"
objSignatureObject.ReplyMessageSignature = "AD Signature"
objDoc.Saved = True
objWord.Quit



pepinho -> RE: Automate E-Mail Signatures (Exchange 2007/Outlook) (2.Nov.2008 10:46:34 AM)

quote:

ORIGINAL: felipeg007

Below is a signature i use. it grabs all the info from AD.

Hello.

I am interested too on automating the Outlook 2007 signatures in my Exchange 2007 environment. Could you explain how do you "inject" the output from your VBS script in the Outlook 2007 signature configuration.

I am at a loss about how to use the script...



Page: [1]